Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)
1!Von VEB Mikroelektronik "Wilhelm Pieck" Muehlhausen
2!Z1013-Version von H.Toepfer
10 WINDOW:CLS
20 PRINT AT(2,6);STRING$(19,"*")
30 PRINT AT(3,6);"*",STRING$(17," "),"*"
40 PRINT AT(4,6);"* LEBENSERWARTUNG *"
50 PRINT AT(5,6);"*",STRING$(17," "),"*"
60 PRINT AT(6,6);STRING$(19,"*")
70 WINDOW 10,31,0,31
80 PRINT "DAS PROGRAMM FUEHRT EINEN "
90 PRINT "'LEBENSERWARTUNGSTEST' DURCH. "
100 PRINT "DAZU SIND EINIGE FRAGEN ZU BE- "
110 PRINT "ANTWORTEN, DIE VERSCHIEDENE AN- "
120 PRINT "GABEN ZUR PERSON UND LEBENSWEISE"
130 PRINT "DES BENUTZERS BEINHALTEN. DIE "
140 PRINT "BEANTWORTUNG DER FRAGEN MUSS MIT"
150 PRINT "JA/NEIN (J/N) ERFOLGEN.":PRINT
160 PRINT "DER TEST GILT NUR FUER PERSONEN "
170 PRINT "ZWISCHEN 16 UND 100 JAHREN."
180 PRINT:PRINT TAB(22);">ENTER<"
190 INPUT "";A$
200 CLS
210 Z=71
220 GOTO 320
230 REM A$
240 PRINT
250 A$=""
260 INPUT "";A$
270 IF A$="JA"OR A$="J"THEN A$="J":GOTO 300
280 IF A$="NEIN"OR A$="N"THEN A$="N":GOTO 300
290 GOTO 250
300 FZ=FZ+1:IF FZ>3 THEN FZ=0:CLS:ELSE PRINT
310 RETURN
320 PRINT "LEBEN SIE IN EINER GROSZSTADT ?":GOSUB 230
330 IF A$="J"THEN Z=Z-2:GOTO 360
340 PRINT "LEBEN SIE IN EINER STADT UNTER 10000 EINWOHNERN ODER AUF DEM"
350 PRINT "LANDE ?":GOSUB 230:IF A$="J"THEN Z=Z+2
360 PRINT "WURDE EINER IHRER GROSSELTERN"
370 PRINT "UEBER 95 JAHRE ALT ?":GOSUB 230
380 IF A$="J"THEN Z=Z+2
390 PRINT "WURDEN ALLE VIER GROSSELTERN"
400 PRINT "AELTER ALS 80 JAHRE ?":GOSUB 230
410 IF A$="J"THEN Z=Z+6
420 PRINT "STARB EIN ELTERNTEIL UNTER 50 JAHREN AN HERZINFARKT ?"
430 GOSUB 230:IF A$="J"THEN Z=Z-4
440 PRINT "LEIDEN ELTERN ODER GESCHWISTER UNTER 50 JAHREN AN KREBS, HERZ-"
450 PRINT "KRANKHEIT ODER DIABETES ?":GOSUB 230:IF A$="J"THEN Z=Z-3
460 PRINT "VERDIENEN SIE UEBER 1200 MARK MONATLICH ?":GOSUB 230
470 IF A$="J"THEN Z=Z-2
480 PRINT "HABEN SIE ABITUR ?":GOSUB 230:IF A$="J"THEN Z=Z+1
490 PRINT "HABEN SIE STUDIERT ODER SIND SIE";
500 PRINT "MEISTER ?":GOSUB 230:IF A$="J"THEN Z=Z+2
510 PRINT "SIND SIE RENTNER UND ARBEITEN SIE NOCH ?":GOSUB 230
520 IF A$="J"THEN Z=Z+3
530 I=0:PRINT "SIND SIE VERHEIRATET ODER LEBEN SIE MIT EINEM PARTNER ZUSAMMEN ?";
540 GOSUB 230
550 IF A$="J"THEN Z=Z+5:GOTO 640
560 PRINT "ALTER ANGEBEN !"
570 PRINT
580 INPUT "";I
590 IF I>100 OR I<16 THEN 580
600 IF I<25 THEN 630
610 Z=Z-INT((I-25)/10)
620 FZ=FZ+1:IF FZ>3 THEN CLS:FZ=0
630 PRINT
640 PRINT "ARBEITEN SIE IM BUERO ?":GOSUB 230:IF A$="J"THEN Z=Z-3:GOTO 660
650 PRINT "ARBEITEN SIE KOERPERLICH ?":GOSUB 230:IF A$="J"THEN Z=Z+3
660 PRINT "TREIBEN SIE AKTIV SPORT ?":GOSUB 230:IF A$="J"THEN Z=Z+4:GOTO 690
670 PRINT "BETAETIGEN SIE SICH 2X PRO WOCHESPORTLICH ?":GOSUB 230
680 IF A$="J"THEN Z=Z+2
690 PRINT "SCHLAFEN SIE MEHR ALS 10 STUNDENTAEGLICH ?":GOSUB 230
700 IF A$="J"THEN Z=Z-4
710 PRINT "WERDEN SIE LEICHT WUETEND ?":GOSUB 230:IF A$="J"THEN Z=Z-3
720 PRINT "NEHMEN SIE DAS LEBEN LEICHT ?":GOSUB 230:IF A$="J"THEN Z=Z+3
730 PRINT "SIND SIE GLUECKLICH ?":GOSUB 230:IF A$="J"THEN Z=Z+1:GOTO 750
740 PRINT "SIND SIE UNGLUECKLICH ?":GOSUB 230:IF A$="J"THEN Z=Z-2
750 PRINT "SIND SIE LETZTES JAHR BEIM SCHNELLFAHREN ERWISCHT WORDEN ?"
760 GOSUB 230:IF A$="J"THEN Z=Z-1
770 PRINT "SIND SIE KETTENRAUCHER ?":GOSUB 230:IF A$="J"THEN Z=Z-8:GOTO 810
780 PRINT "RAUCHEN SIE TAEGLICH 1 PACKUNG ZIGARETTEN ?":GOSUB 230
790 IF A$="J"THEN Z=Z-6:GOTO 810
800 PRINT "RAUCHEN SIE AM TAG 10 ZIGARET- TEN ?":GOSUB 230:IF A$="J"THEN Z=Z-
810 PRINT "TRINKEN SIE MEHR ALS 2 SCHNAEPSEODER BIERE AM TAG ?"
820 GOSUB 230:IF A$="J"THEN Z=Z-1
830 PRINT "HABEN SIE EIN UEBERGEWICHT VON 20 KILO ?":GOSUB 230
840 IF A$="J"THEN Z=Z-8:GOTO 870
850 PRINT "ODER SIND ES 15 KILO ?":GOSUB 230:IF A$="J"THEN Z=Z-4:GOTO 870
860 PRINT "ABER DOCH BESTIMMT 5 KILO ?":GOSUB 230:IF A$="J"THEN Z=Z-2
870 PRINT "LASSEN SIE SICH EINMAL IM JAHR VOM ARZT UNTERSUCHEN ?"
880 GOSUB 230:IF A$="J"THEN Z=Z+2
890 IF I<>0 THEN 990
900 PRINT "SIND SIE 30 BIS 40 JAHRE ALT ?":GOSUB 230
910 IF A$="J"THEN I=35:GOTO 990
920 PRINT "SIND SIE 40 BIS 50 JAHRE ALT ?":GOSUB 230
930 IF A$="J"THEN I=45:GOTO 1000
940 PRINT "SIND SIE 50 BIS 70 JAHRE ALT ?":GOSUB 230
950 IF A$="J"THEN I=55:GOTO 1010
960 PRINT "SIND SIE AELTER ALS 70 JAHRE ?":GOSUB 230
970 IF A$="J"THEN I=75:GOTO 1020
980 GOTO 1030
990 IF I>=30 AND I<40 THEN Z=Z+2
1000 IF I>=40 AND I<50 THEN Z=Z+3
1010 IF I>=50 AND I<70 THEN Z=Z+4
1020 IF I>=70 THEN Z=Z+5
1030 WINDOW:CLS
1040 PRINT AT(3,0);STRING$(31,CHR$(203))
1050 PRINT AT(6,0);"DIE AUSWERTUNG IHRER ANTWORTEN"
1060 PRINT AT(8,0);"ERGIBT EINE LEBENSERWARTUNG VON"
1070 PRINT AT(11,9);Z," JAHREN"
1080 PRINT AT(14,0);STRING$(31,CHR$(203))
1090 PAUSE 30
1100 PRINT AT(20,0);"BEACHTEN SIE:"
1110 PRINT AT(22,0);"DIE ANGABEN ERGEBEN SICH AUS"
1120 PRINT AT(23,0);"STATISTISCHEN MITTELWERTEN."
1130 PRINT AT(24,0);"INDIVIDUELLE BESONDERHEITEN"
1140 PRINT AT(25,0);"KONNTEN NICHT BERUECKSICHTIGT"
1150 PRINT AT(26,0);"WERDEN.ABWEICHUNGEN VOM TEST-"
1160 PRINT AT(27,0);"ERGEBNIS SIND DAHER MOEGLICH."
1170 PAUSE 30
1180 WINDOW 30,31,12,31
1190 INPUT "NOCH EINMAL(J/N)?";A$
1200 IF A$="J"THEN 10
1210 WINDOW:CLS:END
