Screenshot 1 Screenshot 2
2bc0 6332 0000 B ... ANABOREA
https://solutionarchive.com/file/id,12002/ "NORD","SUED","OST","WEST","HINEIN","HINAUS","NEHM","WERF","LEGE" "SCHOEPF","TRINK","KLAU","RAUB","STEHLE","TOETE","REIBE","STREICH" "DREHE","SCHAU","SEHE","BLICK","TAUSCH" "GEBE","TRAENKE","HABE","BESITZ"
Zeichensatz UTF-8+Z1013()+CTRL()-ohne Umlaute(äöüß)

   10 CLEAR 160:WINDOW:CLS:GOSUB 6000:GOTO 160
   20 PRINT "Ausserdem gibt es hier:":GOTO 40
   30 PRINT "Sie besitzen:":KK=0:K=PV
   40 FG=4096:FOR J=1 TO 13:IF K<FG THEN H(J)=0:GOTO 60 
   50 K=K-FG:H(J)=1:IF KK=0 THEN PRINT D$(J)
   60 FG=FG/2:NEXT
   70 RETURN
   80 GV=0:FOR I=1 TO 20:IS=INSTR(G$(I),I1$):IF IS=0 THEN NEXT:ELSE GOTO 100
   90 PRINT AT(31,0);"Pardon, ich verstehe nicht.":PAUSE 55:CLS :RETURN
  100 GV=I:RETURN
  110 INPUT "Was nun ?";I$:IL=LEN(I$):I1$="":TZ=0:FOR I=1 TO IL:A$=MID$(I$,I,1)
  120 IF A$=" "THEN NEXT:ELSE I1$=I1$+A$:NEXT
  130 I1$=I1$+" ":FOR I=1 TO 26:IS=INSTR(H$(I),I1$):IF IS=0 THEN NEXT I:ELSE GOTO 150
  140 GOTO 90
  150 TZ=I:RETURN
  160 IF NV=1 THEN 220
  170 WINDOW 0,25,0,31:CLS       
  180 ON OZ GOSUB 3100,3080,3060,3120,3160,3070,3040,3150,3000,3050
  190 IF OZ>10 THEN ON OZ-10 GOSUB 3030,3000,3040,3030,3010,3140,3030,3040,3110,3130
  200 IF OZ>20 THEN ON OZ-20 GOSUB 3020,3040
  205 IF OZ=6 OR OZ=1 OR OZ=15 THEN WINDOW 28,31,0,31:GOTO 220
  210 WINDOW 28,31,0,31:IF OV(OZ)<>0 THEN KK=0:K=OV(OZ):GOSUB 20
  220 GOSUB 110:IF TZ=0 THEN NV=1:GOTO 160
  225 WINDOW 28,31,0,31:CLS:GV=0
  230 IF TZ>6 AND TZ<25 THEN GOSUB 80:ELSE NV=0:GOTO 236
  235 NV=1
  236 IF TZ>6 AND TZ<25 AND GV=0 THEN 160
  240 ON TZ GOSUB 8000,8000,8000,8000,8000,8000,3200,3270,3270,3300
  250 IF TZ>10 THEN ON TZ-10 GOSUB 3300,3360,3360,3360,3390,3430,3430,3495,3550,3550
  260 IF TZ>20 THEN ON TZ-20 GOSUB 3550,3610,3660,3660,3720,3720
  270 PAUSE 35:CLS:GOTO 160
  500 PRINT AT(20,0);STRING$(31,"")
  510 FOR I=1 TO 6:PRINT AT(2*I+7,20-I);"":PRINT AT(2*I+7,20+I);""
  520 PRINT AT(2*I+8,20-I);"":PRINT AT(2*I+8,20+I);"":NEXT:PRINT AT(8,20);"
  530 PRINT AT(16,15);"         ":RETURN
  540 PRINT AT(0,9);""
  550 PRINT AT(18,9);STRING$(22,""):FOR I=1 TO 17:PRINT AT(I,8);""
  560 PRINT AT(I,31);"":NEXT:PRINT AT(7,15);STRING$(10,"")
  570 PRINT AT(11,15);STRING$(10,""):FOR I=7 TO 11:PRINT AT(I,14);""
  580 PRINT AT(I,25);"":NEXT:FOR I=1 TO 6:PRINT AT(I,I+8);""
  590 PRINT AT(I,31-I);"":PRINT AT(I+11,15-I);"":PRINT AT(I+11,24+I);"":NEXT
  600 PRINT AT(5,9);""
  610 PRINT AT(6,9);"  ":FOR I=7 TO 10:PRINT AT(I,9);"   ":NEXT
  620 PRINT AT(11,9);"  ":PRINT AT(12,9);"" 
  630 RETURN
  640 GOSUB 500:FOR I=1 TO 16:PRINT AT(I,0);A$(I):PRINT AT(I-1,10);A$(I) 
  650 PRINT AT(I+4,25);A$(I):NEXT
  651 KK=1:K=OV(OZ):GOSUB 40:IF H(3)=0 THEN RETURN
  652 PRINT AT(7,2);"":PRINT AT(8,2);""
  653 PRINT AT(9,2);"":PRINT AT(10,2);""
  654 RETURN
  660 GOSUB 500:FOR I=1 TO 16:PRINT AT(I,0);A$(I+16):PRINT AT(I+4,5);A$(I+16)
  670 PRINT AT(I+2,10);A$(I+16):PRINT AT(I+7,24);A$(I+16):NEXT:RETURN
  680 GOSUB 500:FOR I=1 TO 16:PRINT AT(I ,21);A$(I)     
  690 PRINT AT(I-1,7);A$(I):NEXT:RETURN
  700 GOSUB 680 
  710 PRINT AT(10,3);"    "
  720 PRINT AT(11,3);"    "
  730 PRINT AT(12,3);"   "
  740 PRINT AT(13,3);"  "
  750 PRINT AT(14,3);""
  760 PRINT AT(15,3);""
  770 PRINT AT(16,3);"" 
  780 RETURN
  790 GOSUB 500
  800 FOR I=1 TO 16:PRINT AT(I+7,0);A$(I):PRINT AT(I-1,5);A$(I)
  810 PRINT AT(I,11);A$(I):PRINT AT(I+1,20);A$(I):PRINT AT(I,25);A$(I):NEXT
  820 RETURN
  830 GOSUB 790:FOR I=1 TO 16:PRINT AT(I,24);"        ":NEXT
  840 PRINT AT(8,24);" "
  850 PRINT AT(9,24);""
  860 PRINT AT(10,24);""
  870 PRINT AT(11,24);" "
  880 PRINT AT(12,24);"" 
  890 PRINT AT(13,24);"" 
  900 PRINT AT(14,24);"" 
  910 PRINT AT(15,24);""
  920 PRINT AT(16,24);"  ":RETURN
  930 GOSUB 790:IF C(1)=1 THEN RETURN
  940 PRINT AT(18,8);"       "
  950 PRINT AT(19,8);"       "
  960 PRINT AT(20,8);"  " 
  970 PRINT AT(21,8);"     " 
  980 PRINT AT(22,8);"   "
  990 PRINT AT(23,8);"     "
 1000 PRINT AT(24,8);"     "
 1010 RETURN
 1020 GOSUB 660:IF C(2)=1 THEN RETURN
 1030 GOSUB 660:IF C(2)=1 THEN RETURN:ELSE PRINT AT(0,17);"":PRINT AT(5,16);" "
 1040 PRINT AT(1,17);"":PRINT AT(6,16);" "
 1050 PRINT AT(2,17);" ":PRINT AT(7,17);""     
 1060 PRINT AT(3,17);" ":PRINT AT(8,17);" "      
 1070 PRINT AT(4,17);"":PRINT AT(9,17);" "      
 1080 PRINT AT(10,17);" ":PRINT AT(11,17);" "      
 1090 PRINT AT(12,17);" ":PRINT AT(13,17);"   "     
 1100 PRINT AT(14,17);"   ":PRINT AT(15,17);"   "         
 1110 RETURN
 1120 PRINT:PRINT:PRINT:PRINT
 1130 PRINT "         "
 1140 PRINT "                "
 1150 PRINT "                          "               
 1160 PRINT "                         "               
 1170 PRINT "                         "         
 1180 PRINT "                       "            
 1190 PRINT "                     "            
 1200 PRINT "                    "
 1210 PRINT "                     "
 1220 PRINT "               "
 1230 PRINT "           "
 1240 FOR I=1 TO 16:PRINT AT(I+9,24);A$(I+16):NEXT:RETURN
 1250 PRINT:PRINT:PRINT:PRINT
 1260 PRINT "        
 1270 PRINT "      "
 1280 PRINT "     "
 1290 PRINT "    "
 1300 PRINT "   "
 1310 PRINT "  "
 1320 PRINT "  " 
 1330 PRINT "  "      
 1340 PRINT "  "                                  
 1350 PRINT "  "
 1360 PRINT "  "
 1370 PRINT "  " 
 1380 PRINT "  " 
 1390 PRINT "  " 
 1400 PRINT " "   
 1410 FOR I=1 TO 16:PRINT AT(I+1,20);A$(I):NEXT:RETURN
 1420 GOSUB 680:PRINT " ":PRINT " ":PRINT " ":PRINT " ":PRINT " "
 1430 PRINT "      "
 1440 PRINT "     "
 1450 PRINT "      "
 1460 PRINT "       "
 1470 PRINT "      "
 1480 PRINT "     "
 1490 PRINT "     "
 1500 PRINT "     "
 1510 PRINT "     "
 1520 PRINT "     "
 1530 PRINT "     ":RETURN
 1540 PRINT "     "
 1550 PRINT "     "
 1560 PRINT "     "
 1570 PRINT "       "
 1580 PRINT "    "
 1590 PRINT "               ";
 1600 PRINT "          ";
 1610 PRINT "        ";
 1620 PRINT "           ";
 1630 PRINT "        ";
 1640 PRINT "           ";
 1650 PRINT "           ";
 1660 PRINT "           ";
 1670 PRINT "          ";
 1680 PRINT "        ";
 1690 PRINT "     ";
 1700 PRINT "     ";
 1710 PRINT "     ";
 1720 RETURN
 1730 GOSUB 540:IF C(3)=0 THEN FOR I=9 TO 12:PRINT AT(I,29);"":NEXT
 1740 IF C(3)=0 THEN PRINT AT(13,29);"":PRINT AT(14,29);""
 1750 PRINT AT(8,17);" "
 1760 PRINT AT(9,17);" "
 1770 PRINT AT(10,17);""
 1780 PRINT AT(11,17);"  "
 1790 PRINT AT(12,17);"    "
 1800 PRINT AT(13,17);"    "
 1810 PRINT AT(14,17);"     "
 1820 PRINT AT(15,17);"  "
 1830 PRINT AT(16,17);"        ":RETURN
 1840 GOSUB 540:IF C(4)=1 THEN RETURN
 1850 PRINT AT(3,23);"":PRINT AT(4,23);"":PRINT AT(5,23);"    "
 1860 PRINT AT(6,23);"    ":PRINT AT(7,23);"    "
 1870 PRINT AT(8,23);" " 
 1880 FOR I=9 TO 12:PRINT AT(I,25);"":NEXT
 1890 PRINT AT(13,25);"   "
 1900 PRINT AT(14,25);"   "
 1910 PRINT AT(15,24);"  ":RETURN
 3000 PRINT AT(26,0);"SIE SIND AN EINER WEGKREUZUNG  ":GOSUB 640:RETURN
 3010 PRINT AT(26,0);"DER WEG GABELT SICH            ":GOSUB 640:RETURN
 3020 PRINT AT(26,0);"SIE SIND IM DICHTEN WALD       ":GOSUB 790:RETURN
 3030 PRINT AT(26,0);"SIE BEFINDEN SICH IM WALD      ":GOSUB 660:RETURN
 3040 PRINT AT(26,0);"IM TIEFEN WALDE                ":GOSUB 680:RETURN
 3050 PRINT AT(26,0);"HIER IST EINE QUELLE AM WEGE   ":GOSUB 700:RETURN
 3060 PRINT AT(26,0);"HIER STEHT EIN DURSTIGES PFERD ":GOSUB 930
 3065 IF C(1)=1 THEN PRINT AT(26,0);"UNWEIT IST EINE BAERENHOEHLE      ":RETURN
 3068 RETURN
 3070 PRINT AT(26,0);"EIN EIGENARTIGER FELSEN        ":GOSUB 830:RETURN
 3080 IF C(2)=0 THEN PRINT AT(25,0);"MERKWUERDIG, DER FELSEN SIEHT   
 3090 IF C(2)=0 THEN PRINT AT(26,0);"AUS WIE EIN MENSCH.         ":GOSUB 1030:RETURN
 3095 PRINT AT(26,0);"HIER LEBT EIN HOLZFAELLER.":GOSUB 1250:RETURN
 3100 PRINT AT(26,0);"IM HEXENHAUS                   ":GOSUB 1730:RETURN
 3110 PRINT AT(26,0);"IM HAUS DES ZAUBERERS          ":GOSUB 1840:RETURN
 3120 PRINT AT(26,0);"VOR DEM HEXENHAUS              ":GOSUB 1250:RETURN 
 3130 PRINT AT(26,0);"VOR DEM HAUS DES ZAUBERERS     ":GOSUB 1250:RETURN
 3140 PRINT AT(26,0);"EIN VERFALLENES SCHLOSS        ":GOSUB 1540:RETURN
 3150 PRINT AT(26,0);"DER EINGANG ZU EINEM BERGWERK  ":GOSUB 1420:RETURN
 3160 PRINT AT(26,0);"EIN TEICH IM WALD              ":GOSUB 1120:RETURN
 3200 KK=1:K=OV(OZ):GOSUB 40:IF H(GV)=0 THEN PRINT "DAS GEHT NICHT.":RETURN
 3205 IF C(10)>=3 THEN PRINT "SOVIEL KOENNEN SIE NICHT TRAGEN.":RETURN
 3210 IF GV=7 THEN PRINT "DIES IST NICHT MOEGLICH.":RETURN
 3220 IF GV<>10 THEN OV(OZ)=OV(OZ)-DV(GV):PV=PV+DV(GV):C(10)=C(10)+1
 3230 IF GV<>10 THEN PRINT "ERLEDIGT!":RETURN
 3240 GOSUB 20000:PRINT "DAS GELD VERWANDELT SICH IN EIN"
 3250 PRINT "BUENDEL GIFTIGER SCHLANGEN. EINE"
 3260 PRINT "FALLE WAASAPS DER SIE ERLAGEN!!!":CLEAR:GOTO 30000
 3270 KK=1:K=PV:GOSUB 40
 3280 IF H(GV)=0 THEN PRINT "DAS HABEN SIE NICHT!":RETURN
 3290 PRINT "OKAY!":PV=PV-DV(GV):OV(OZ)=OV(OZ)+DV(GV):C(10)=C(10)-1:RETURN
 3300 IF OZ<>5 AND OZ<>10 THEN PRINT "DAS GEHT HIER NICHT.":RETURN
 3310 IF GV<>7 THEN PRINT "DAS IST UNMOEGLICH.":RETURN
 3320 KK=1:K=PV:GOSUB 40:IF H(7)=0 AND H(6)=1 THEN PV=PV+64
 3325 IF H(6)=0 THEN PRINT "DAS GEHT NICHT SO.":RETURN
 3330 IF OZ=10 THEN PRINT "ERLEDIGT !":RETURN
 3340 GOSUB 20000:IF OZ=5 THEN PRINT "DAS WASSER WAR VERGIFTET."
 3350 IF OZ=5 THEN PRINT "RUHEN SIE IN FRIEDEN!":CLEAR:GOTO 30000
 3360 IF OZ<>1 OR GV<>14 OR C(3)=1 THEN PRINT "SO GEHT DAS NICHT.":RETURN
 3370 CLS:PRINT "DIE HEXE FLEHT UND BETTELT. SIE WILL ";
 3380 NV=0:PRINT "IHREN BESEN WIEDER HABEN.":C(3)=1:PAUSE 25:RETURN
 3390 IF OZ<>19 OR GV<>20 THEN PRINT "WAS SOLL DAS?":RETURN
 3400 IF C(2)=1 THEN PRINT "SIE HABEN DEN ZAUBERER BESIEGT!":C(4)=1:RETURN
 3410 GOSUB 20000:PRINT "SIE HATTEN KEINE WAFFE DABEI!"
 3420 PRINT "WAASAP HAT SIE VERNICHTET.":CLEAR:GOTO 30000
 3430 IF OZ<>2 OR C(2)=1 THEN PRINT "DAS FUEHRT ZU NICHTS.":RETURN
 3440 IF GV<>1 THEN PRINT "WAS SOLL DAS BEDEUTEN?":RETURN
 3450 KK=1:K=PV:GOSUB 40
 3460 IF H(1)=0 THEN PRINT "WELCHE LAMPE?":RETURN
 3470 CLS:PRINT "EIN GUTER GEIST ENTWEICHT UND":PRINT "ERLOEST";
 3480 PRINT " DEN HOLZFAELLER":PAUSE 50:CLS:PRINT "ER SCHENKT IHNEN DAFUER"
 3490 NV=0:PRINT "SEINE WUNDERAXT.":C(2)=1:PAUSE 45:CLS:RETURN
 3495 IF GV<>2 THEN PRINT "DAS IST NICHT DRIN.":RETURN
 3496 KK=1:K=PV:GOSUB 40:IF H(2)=0 THEN PRINT "WELCHEN RING?":RETURN
 3500 GOSUB 20000:IF C(4)=0 THEN PRINT "NOCH HAT WAASAP MACHT UEBER DEN"
 3510 IF C(4)=0 THEN PRINT "WUNDERRING. SEIN BOESER ZAUBER"
 3520 IF C(4)=0 THEN PRINT "TOETET DICH.":CLEAR:GOTO 30000
 3530 IF OZ<>16 OR H(3)=0 THEN PRINT "DAS BRINGT HIER NICHTS EIN.":RETURN
 3540 GOSUB 12000
 3550 IF OZ<>1 AND OZ<>6 AND OZ<>15 THEN PRINT "HIER IST NICHTS ZU SEHEN.":RETURN
 3560 KK=1:K=OV(OZ):GOSUB 40
 3570 IF GV=17 AND OZ=1 AND C(3)=0 THEN PRINT "DA STEHT EIN BESEN.":RETURN
 3580 IF GV=18 AND OZ=6 AND H(2)=1 THEN PRINT "DA LIEGT EIN SIEGELRING":RETURN
 3590 IF GV=19 AND OZ=15 AND H(3)=1 THEN PRINT "HIER HAENGT ";D$(3):RETURN
 3600 PRINT "DAS IST NICHT NOTWENDIG.":RETURN
 3610 IF OZ<>1 OR GV<>14 THEN PRINT "DAS GEHT NICHT.":RETURN
 3620 IF C(3)=0 THEN PRINT "DAS KOENNEN SIE GAR NICHT.":RETURN
 3630 PV=PV+4096:CLS:PRINT "DIE HEXE IST BEGEISTERT VON DEM";
 3640 PRINT "  ENTGEGENKOMMEN UND SCHENKT DIR EINE ";
 3650 PRINT "LAMPE.":PAUSE 55:RETURN
 3660 IF GV=14 THEN 3610
 3670 IF OZ<>3 OR(GV<>7 AND GV<>16)THEN PRINT "DAS GEHT LEIDER NICHT.":RETURN
 3680 KK=1:K=PV:GOSUB 40
 3690 IF H(7)=0 THEN PRINT "WOMIT?":RETURN
 3695 IF C(1)=1 THEN PRINT "DAS IST UEBERFLUESSIG.":RETURN
 3700 C(1)=1:PRINT "DAS ZAUBERPFERD WIRD DIR AUS":NV=0
 3710 PRINT "DANKBARKEIT ZU DIENSTEN SEIN.":RETURN
 3720 WINDOW 0,26,0,31:CLS:GOSUB 30
 3730 PAUSE 70:CLS:NV=0:RETURN
 6000 OZ=12:NV=0:DIM D$(20),H(16),G$(20),H$(26),C(10),DV(20),OV(22)
 6010 DATA "NORD","SUED","OST","WEST","HINEIN","HINAUS","NEHM","WERF","LEGE"
 6020 DATA "SCHOEPF","TRINK","KLAU","RAUB","STEHLE","TOETE","REIBE","STREICH"
 6030 DATA "DREHE","SCHAU","SEHE","BLICK","TAUSCH"
 6040 DATA "GEBE","TRAENKE","HABE","BESITZ"
 6050 FOR I=1 TO 26:READ H$(I):NEXT
 6060 DATA "LAMPE","EINE ALTE LAMPE",4096
 6070 DATA "RING","EINEN SIEGELRING",2048
 6080 DATA "VOGEL","EINEN VOGELKAEFIG MIT INSASSE",1024
 6090 DATA "HOLZ","GEHACKTES HOLZ",512,"SEIL","EIN SEIL",256
 6100 DATA "EIMER","EINEN ZINKEIMER",128,"WASSER","WASSER",64
 6110 DATA "STIEFEL","ZWEI STIEFEL",32,"GEWAND","EIN ROTES GEWAND",16
 6120 DATA "GELD","VIEL GELD",8,"KOMPASS","EINEN KOMPASS",4
 6130 DATA "ORGEL","EINE DREHORGEL",2,"FEUER","EIN ALTES FEUERZEUG",1
 6140 DATA "BESEN","",0,"AXT","",0,"PFERD","",0
 6145 DATA "WAND","",0,"FELS","",0,"BAUM","",0,"ZAUBER","",0
 6150 FOR I=1 TO 20:READ G$(I),D$(I),DV(I):NEXT
 6160 DATA 0,0,0,0,0,2048,4,128,16,0,256,0,512,32,1024,0,8,2,0,0,1,0
 6170 FOR I=1 TO 22:READ OV(I):NEXT:PV=0
 6180 DATA "     ","   "
 6190 DATA "  ","   "
 6200 DATA "     ","    "
 6210 DATA "  ","    "
 6220 DATA "    ","    "
 6230 DATA "   ","     "
 6240 DATA "    ","     "
 6250 DATA "  ","     "
 6260 DATA "    ","      "
 6270 DATA "    ","      "
 6280 DATA "    ",""
 6290 DATA "    ","   "
 6300 DATA "    ","   "
 6310 DATA "    ","   "
 6320 DATA "    ","   "
 6330 DATA "   ","   "
 6340 DIM A$(32):FOR I=1 TO 16:READ A$(I),A$(I+16):NEXT
 6350 WINDOW:CLS:PRINT AT(10,10);"ADVENTURE III":PAUSE 30 
 6360 A$="A":B$="N":C$="B":D$="O":E$="R":F$="E":G$=" "
 6361 FOR A=1 TO 10:PRINT AT(10,A-1);G$:PRINT AT(10,A);A$:PAUSE 1:NEXT
 6362 FOR B=30 TO 10 STEP-1:PRINT AT(B+1,11);G$:PRINT AT(B,11);B$:PAUSE 1:NEXT
 6363 FOR C=1 TO 10:PRINT AT(C-1,12);G$:PRINT AT(C,12);A$:PAUSE 1:NEXT
 6364 FOR D=30 TO 10 STEP-1:PRINT AT(D+1,13);G$:PRINT AT(D,13);C$:PAUSE 1:NEXT
 6365 FOR E=1 TO 10:PRINT AT(E-1,14);G$:PRINT AT(E,14);D$:PAUSE 1:NEXT
 6366 FOR F=30 TO 10 STEP-1:PRINT AT(F+1,15);G$:PRINT AT(F,15);E$:PAUSE 1:NEXT
 6380 FOR G=1 TO 10:PRINT AT(G-1,16);G$:PRINT AT(G,16);F$:PAUSE 1:NEXT
 6390 FOR H=30 TO 17 STEP-1:PRINT AT(10,H+1);G$:PRINT AT(10,H);A$:PAUSE 1:NEXT
 6391 X=10:Y=16
 6392 X=X+1:Y=Y+1:WINDOW X,X+1,Y,Y+1:PRINT CHR$(30):PAUSE 6:CLS:IF Y<30 THEN GOTO 6392
 6400 WINDOW 14,31,0,31:PRINT "Spielidee     : M. Siedentopf":PRINT
 6405 PRINT "Version Z 1013: K. Rothe":PAUSE 50:WINDOW:WINDOW 14,20,0,31        
 6610 FOR I=0 TO 95:PRINT "";:PAUSE 1:PRINT "";:NEXT:PAUSE 50:WINDOW 16,18,3,28:CLS 
 6611 PRINT:PRINT "  ANLEITUNG UEBER EDITEX ":WINDOW:PAUSE 60:WINDOW:CLS:RETURN
 8000 ON OZ GOTO 8030,8100,8130,8060,8180,8240,8280,8330 
 8010 IF OZ>8 THEN ON OZ-8 GOTO 8380,8430,8480,8510,8560,8600,8630,8680
 8020 IF OZ>16 THEN ON OZ-16 GOTO 8710,8750,8780,8800,8840,8870
 8030 ON TZ GOTO 8040,8040,8040,8040,8040,8050
 8040 PRINT "Dorthin koennen Sie nicht gehen":RETURN
 8050 OZ=4:RETURN
 8060 ON TZ GOTO 8040,8070,8040,8080,8090,8040
 8070 OZ=7:RETURN
 8080 OZ=3:RETURN
 8090 OZ=1:RETURN
 8100 ON TZ GOTO 8040,8110,8120,8040,8040,8040
 8110 OZ=8:RETURN
 8120 OZ=3:RETURN
 8130 ON TZ GOTO 8140,8150,8160,8170,8040,8040
 8140 GOSUB 20000:PRINT "Ein BAER hat Sie gefressen.":CLEAR:GOTO 30000
 8150 OZ=5:RETURN
 8160 OZ=4:RETURN
 8170 OZ=2:RETURN
 8180 ON TZ GOTO 8190,8200,8210,8220,8040,8040
 8190 OZ=3:RETURN
 8200 OZ=9:RETURN
 8210 OZ=6:RETURN
 8220 GOSUB 20000:PRINT "Sie wurden im Wald von KOBOLDEN"
 8230 PRINT "verzaubert.":CLEAR:GOTO 30000
 8240 ON TZ GOTO 8040,8250,8260,8270,8040,8040
 8250 OZ=10:RETURN
 8260 OZ=7:RETURN
 8270 OZ=5:RETURN
 8280 ON TZ GOTO 8290,8300,8310,8320,8040,8040
 8290 OZ=4:RETURN
 8300 GOSUB 20000:PRINT "Sie fielen von einem FELSEN.":CLEAR:GOTO 30000
 8310 GOSUB 20000:PRINT "Ein ZENTAUR hat Sie entfuehrt.":CLEAR:GOTO 30000
 8320 OZ=6:RETURN
 8330 ON TZ GOTO 8340,8350,8360,8370,8335,8040
 8335 GOSUB 20000:PRINT "Ein FLUCH lag auf diesen Ort.":PRINT "  IHR ENDE IST DA."
 8336 GOTO 30000
 8340 OZ=2:RETURN
 8350 OZ=11:RETURN
 8360 OZ=9:RETURN
 8370 GOSUB 20000:PRINT "Sie sind im WALDE verschollen.":CLEAR:GOTO 30000
 8380 ON TZ GOTO 8390,8400,8410,8420,8040,8040
 8390 OZ=5:RETURN
 8400 OZ=12:RETURN
 8410 OZ=10:RETURN
 8420 OZ=8:RETURN
 8430 ON TZ GOTO 8440,8450,8460,8470,8040,8040
 8440 OZ=6:RETURN
 8450 OZ=13:RETURN
 8460 GOSUB 20000:PRINT "Sie sind in ein MOOR geraten.":CLEAR:GOTO 30000 
 8470 OZ=9:RETURN
 8480 ON TZ GOTO 8490,8040,8500,8040,8040,8040
 8490 OZ=8:RETURN
 8500 OZ=12:RETURN
 8510 ON TZ GOTO 8520,8530,8540,8550,8040,8040
 8520 OZ=9:RETURN
 8530 OZ=14:RETURN
 8540 OZ=13:RETURN
 8550 OZ=11:RETURN
 8560 ON TZ GOTO 8570,8580,8040,8590,8040,8040
 8570 OZ=10:RETURN
 8580 OZ=15:RETURN
 8590 OZ=12:RETURN
 8600 ON TZ GOTO 8610,10000,8620,8040,8040,8040
 8610 OZ=12:RETURN
 8620 OZ=15:RETURN
 8630 ON TZ GOTO 8640,8650,8660,8670,8040,8040
 8640 OZ=13:RETURN
 8650 GOSUB 20000:IF C(1)=0 THEN PRINT "Sie sind in die SCHLUCHT gestuerzt.":CLEAR
 8651 GOTO 30000
 8655 OZ=18:RETURN
 8660 OZ=16:RETURN
 8670 OZ=14:RETURN
 8680 ON TZ GOTO 8040,10000,8690,8700,8335,8040
 8690 GOSUB 20000:PRINT "Sie fielen in eine FALLGRUBE und verhungerten.":CLEAR  
 8691 GOTO 30000
 8700 OZ=15:RETURN
 8710 ON TZ GOTO 10000,8720,8730,8740,8040,8040
 8720 OZ=20:RETURN
 8730 OZ=18:RETURN
 8740 GOSUB 20000:PRINT "Sie verliefen sich imTIEFEN WALD und starben.":CLEAR   
 8741 GOTO 30000
 8750 ON TZ GOTO 10000,8760,8740,8770,8040,8040
 8760 OZ=22:RETURN
 8770 OZ=17:RETURN
 8780 ON TZ GOTO 8040,8040,8040,8040,8040,8790
 8790 OZ=20:RETURN
 8800 ON TZ GOTO 8810,8040,8820,8040,8830,8040
 8810 OZ=17:RETURN
 8820 OZ=21:RETURN
 8830 OZ=19:RETURN
 8840 ON TZ GOTO 8650,8040,8850,8860,8040,8040
 8850 OZ=22:RETURN
 8860 OZ=20:RETURN
 8870 ON TZ GOTO 8880,8040,8040,8890,8040,8040
 8880 OZ=18:RETURN
 8890 OZ=21:RETURN
10000 IF C(1)=1 THEN ON OZ-13 GOTO 10020,10030,10040,10050,10060
10010 PRINT "Die Schlucht ist so nicht zu     ueberwinden.":RETURN
10020 OZ=17:RETURN
10030 OZ=15:RETURN
10040 OZ=18:RETURN
10050 OZ=14:RETURN
10060 OZ=16:RETURN
12000 WINDOW:CLS:OUT 136,36:WINDOW 5,31,0,31
12010 PRINT "Dies war der WEG DER ERLOESUNG.":PRINT:BEEP:PAUSE 30
12020 PRINT "Der Vogelkaefig verschwindet und LIGEIA ";
12030 PRINT "steht in Ihrer Pracht   vor Dir.";:PAUSE 20:PRINT "Nun ";
12040 PRINT "wird es nur noch von Deinem ";"Liebreiz ";:PAUSE 30
12050 PRINT "abhaengen, ob  Du auch Ihr Herz ";:PAUSE 20
12060 PRINT "eringen kannst oder nur das halbe ";:PAUSE 30
12070 PRINT "Koenigreich. Doch ich glaube einen ";:PAUSE 30
12080 PRINT "so guten   und tapferen Mann wird ";:PAUSE 30
12090 PRINT "KEINE   Frau abweisen.":PAUSE 40:PRINT "Sei also gluecklich ";:PAUSE 9
12100 PRINT "und feiere  ein grosses Fest !!"
12110 PAUSE 200:OUT 136,0:CLS:END
20000 PAUSE 30:WINDOW:FOR I=0 TO 31 STEP 3:PRINT AT(I,0);STRING$(95," "):NEXT I:PAUSE 1
20010 WINDOW 15,31,0,31:RETURN
30000 PRINT "DIES IST DAS SPIELENDE !":PRINT:PRINT
30010 PRINT "ABER ICH GLAUBE, DASS SIE SICH  NICHT SCHON GESCHLAGEN GEBEN."
30020 PRINT:PAUSE 50:PRINT:PRINT "ALSO O.K. ES GEHT GLEICH WIEDER LOS !" 
30030 PAUSE 50:WINDOW:CLS:RUN